_token

_rewardAmountPerAddress

_users

addWhitelist

claimReadyByAddress

claimTokens

cooldownTime

owner

pendingBalanceByAddress

rewardAmountPerAddress

token

whitelistByAddress

//SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";

contract Airdrop is ReentrancyGuard {
    address public owner;
    IERC20 public token;
    uint256 public rewardAmountPerAddress;
    uint256 public cooldownTime = 30 days;

    mapping(address => bool) public whitelistByAddress;
    mapping(address => uint256) public pendingBalanceByAddress;
    mapping(address => uint256) public claimReadyByAddress;

    constructor(address _token, uint256 _rewardAmountPerAddress) {
        owner = msg.sender;
        token = IERC20(_token);
        rewardAmountPerAddress = _rewardAmountPerAddress;
    }

    modifier onlyOwner() {
        require(msg.sender == owner, 'You must be the owner.');
        _;
    }

    /**
     * @notice Calculate the percentage of a number.
     * @param x Number.
     * @param y Percentage of number.
     * @param scale Division.
     */
    function mulScale (uint x, uint y, uint128 scale) internal pure returns (uint) {
        uint a = x / scale;
        uint b = x % scale;
        uint c = y / scale;
        uint d = y % scale;

        return a * c * scale + a * d + b * c + b * d / scale;
    }

    /**
     * @notice Function that allows to add investors to the whitelist.
     * @param _users Array of addresses to be added to the whitelist.
     */
    function addWhitelist(address[] memory _users) public onlyOwner {
        for(uint16 i = 0; i < _users.length; i++) {
            require(_users[i] != address(0), 'Invalid address.');
            require(!whitelistByAddress[_users[i]], 'The address is already on the whitelist.');

            whitelistByAddress[_users[i]] = true;
            claimReadyByAddress[_users[i]] = block.timestamp + cooldownTime;
            pendingBalanceByAddress[_users[i]] = rewardAmountPerAddress;
        }
    }

    /**
     * @notice Function that allows users to claim their available tokens.
     */
    function claimTokens() public nonReentrant {
        require(whitelistByAddress[msg.sender], "You must be on the whitelist.");
        require(claimReadyByAddress[msg.sender] <= block.timestamp, "You can't claim now.");
        require(pendingBalanceByAddress[msg.sender] > 0, "Insufficient pending balance.");

        uint256 _withdrawableTokensBalance = mulScale(rewardAmountPerAddress, 1000, 10000); // 1000 basis points = 10%.
        uint256 _contractBalance = token.balanceOf(address(this));
        require(_contractBalance >= _withdrawableTokensBalance, "Insufficient contract balance.");

        claimReadyByAddress[msg.sender] += cooldownTime;
        pendingBalanceByAddress[msg.sender] -= _withdrawableTokensBalance;

        token.transfer(msg.sender, _withdrawableTokensBalance);
    }
}


spender

value

Approval

from

Transfer

allowance

amount

approve

account

balanceOf

totalSupply

transfer

transferFrom

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}


// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        // On the first call to nonReentrant, _notEntered will be true
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;

        _;

        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}


Token distributor that allows the owner to distribute tokens to a list of users over 300 days. 10% unlocks every 30 days, and users are able to claim 10% of the initially allocated tokens. Users pay to claim their share each month.

Airdrop over time

This function adds a list of addresses to the whitelist of the contract. It requires that the address is not 0 and that it is not already on the whitelist. It then sets the claimReadyByAddress to the current block timestamp plus the cooldownTime, and sets the pendingBalanceByAddress to the rewardAmountPerAddress. (autogenerated documentation)

This function allows whitelisted users to claim tokens from the contract. It requires that the user is on the whitelist, that the cooldown time has passed, and that the user has a sufficient pending balance. It then calculates the withdrawable token balance, checks that the contract has sufficient balance, and then transfers the tokens to the user. (autogenerated documentation)

This function is an internal pure function that takes in three unsigned integers (x, y, and scale) and returns an unsigned integer. It performs a multiplication of x and y, scaling the result by the value of scale. It does this by first dividing x and y by scale, and then multiplying the quotients and the remainders separately. The result is then added together and returned. (autogenerated documentation)